// This program allows you to communicate and configure
// the HC-06 (Slave Only) Bluetooth module using the 
// Arduino serial monitor
//
// Connections
// HC-06 (Slave Only)    Arduino
// TX                    2 (RX)
// RX                    3 (TX)
// VCC                   5V
// GND                   GND

// Serial Monitor settings should be No line ending and 9600 baud
// AT commands to type in the monitor      Response
//    for the HT-06 (Slave Only)
// AT                                      OK               it's working
// AT+VERSION                              linvorV1.8
// AT+BAUD4            for 9600            OK9600
// AT+BAUD6            for 38400           OK38400
// AT+BAUD8            for 115200          OK115200
// AT+NAMERobotsForFun-BT                  OKsetname        set the name
// AT+PIN1234                              OKsetpin         set the password
//
// commands are case sensitive

// Click on the Send button to send the command to the Bluetooth
// The response will print in the monitor

// c 2015 Enoch Hwang


#include "SoftwareSerial.h"
SoftwareSerial BTSerial(2, 3); // RX, TX

void setup() {
  // If you do not get the initial OK, it is because the connection and/or the baud is wrong
  // If you see garbage, it is because the baud is wrong
  // The default baud rate for the HC-06 (Slave only) Bluetooth module is 9600
  Serial.begin(9600);     // baud rate for the Serial monitor
  BTSerial.begin(9600);   // // The default baud rate is 9600

  Serial.println("Enter AT commands:");  
  // if connection and baud are correct then should get OK response 
  BTSerial.write("AT");  
}

void loop() {
  if (BTSerial.available()){
    Serial.write(BTSerial.read());
  }
  if (Serial.available())
    BTSerial.write(Serial.read()); 
}

// This program allows you to communicate and configure
// the HC-05 (Master/Slave) Bluetooth module using the 
// Arduino serial monitor
//
// Connections
// HC-05 Master/Slave    Arduino
// TX                    2 (RX)
// RX                    3 (TX)
// KEY/EN                5V (only for the new version with the gold check mark)
// VCC                   5V
// GND                   GND

// Serial Monitor settings should be Both NL & CR and 9600 baud
// AT commands to type in the monitor      Response
//    for the HT-05 (Master/Slave)
// AT                                      OK
// AT+VERSION?                             +VERSION:4.0-20190815
// AT+UART?                                +UART:9600,0,0           default 9600, 1 stop bit, no parity
// AT+UART=9600,0,0                        OK                       set to 9600, 1 stop bit, no parity
// AT+NAME?                                +NAME:HC-05              get the name (new version only)
// AT+NAME=RobotsForFun-BT                 +NAME:RobotsForFun-BT    set the name
// AT+PSWD?                                +PSWD:1234               get the password
// AT+PSWD=1234                            OK                       set the password
// invalid command                         ERROR:[0]
//
// commands are case sensitive

// Click on the Send button to send the command to the Bluetooth
// The response will print in the monitor
//
// c 2015 Enoch Hwang


#include "SoftwareSerial.h"
SoftwareSerial BTSerial(2, 3); // RX, TX

void setup() {
  // If you do not get the initial OK, it is because the connection and/or the baud is wrong
  // If you see garbage, it is because the baud is wrong
  // The default baud rate for the HC-05 (Master/Slave) Bluetooth module is 38400
  Serial.begin(9600);     // baud rate for the Serial monitor
  BTSerial.begin(38400);  // The default baud rate is 38400

  Serial.println("Enter AT commands:");
  // if the connection and the baud rate are correct then should get OK response on the monitor
  BTSerial.write("AT\r\n");
  delay(500);
  BTSerial.write("AT+VERSION?\r\n");
}

void loop() {
  if (BTSerial.available()){
    Serial.write(BTSerial.read());
  }
  if (Serial.available())
    BTSerial.write(Serial.read()); 
}

// Control a LED wirelessly using Bluetooth

#include "SoftwareSerial.h"
SoftwareSerial BTSerial(2, 3); // RX, TX

const int led = 13;

void setup() {
  pinMode(led, OUTPUT);
  BTSerial.begin(9600);  // baud rate for the Bluetooth
  BTSerial.println("Press 1=on; 0=off");
}

void loop() {
  if(BTSerial.available()) {  // check if there's any incoming data on the Bluetooth
    char value = BTSerial.read();  // if there is then read in the data

    if (value == '1') {         // turn on led
      digitalWrite(led, HIGH);
      BTSerial.println("LED on");
    } else if (value == '0') {  // turn off led
      digitalWrite(led, LOW);
      BTSerial.println("LED off");
    } else {                    // invalid character
      BTSerial.println("Press 1=on; 0=off");
    }
  }
}